Requirements:

• CyberArk PrivateArk
• Microsoft Windows 7 or higher

PrivateArkWorkspaceLink_v1.0.vbs

' ##############################################################################
' #                                Lupi Gabriel                                #
' #                             www.lupigabriel.it                             #
' #                            info@lupigabriel.it                             #
' ##############################################################################
' #            Copyright (c) 2014 Lupi Gabriel All rights reserved.            #
' ##############################################################################
' # VERSION    : 1.0                                                           #
' # FILE       : PrivateArkWorkspaceLink_v1.0.vbs                              #
' # CLASS      : Script                                                        #
' # LANGUAGE   : VB Script                                                     #
' # OUPUT      : "%UserProfile%\Links"                                         #
' ##############################################################################



On Error Resume Next

Set oShell = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(oShell.ExpandEnvironmentStrings("%PROGRAMFILES%") & "\PrivateArk\Client\Arkui.exe") = True Or objFSO.FileExists(oShell.ExpandEnvironmentStrings("%PROGRAMFILES(X86)%") & "\PrivateArk\Client\Arkui.exe") = True Then
	If objFSO.FileExists(oShell.ExpandEnvironmentStrings("%USERPROFILE%") & "\Links\Workspace.lnk") = False Then
		If objFSO.FolderExists(oShell.ExpandEnvironmentStrings("%APPDATA%") & "\CyberArk\PrivateArk\Workspace") = True Then
			Set oShortCut = oShell.CreateShortcut(oShell.ExpandEnvironmentStrings("%USERPROFILE%") & "\Links\Workspace.lnk")
			oShortCut.TargetPath = oShell.ExpandEnvironmentStrings("%APPDATA%") & "\CyberArk\PrivateArk\Workspace"
			oShortCut.Save
		End If
	End If
Else
	If objFSO.FileExists(oShell.ExpandEnvironmentStrings("%USERPROFILE%") & "\Links\Workspace.lnk") = True Then
		objFSO.DeleteFile oShell.ExpandEnvironmentStrings("%USERPROFILE%") & "\Links\Workspace.lnk"
	End If
End If

Tested on the following Microsoft OS versions:

• Microsoft Windows XP (32bit)
• Microsoft Windows 7 (32bit)

ClearCachedProfile_v1.0.vbs

' ##############################################################################
' #                                Lupi Gabriel                                #
' #                             www.lupigabriel.it                             #
' #                            info@lupigabriel.it                             #
' ##############################################################################
' #            Copyright (c) 2014 Lupi Gabriel All rights reserved.            #
' ##############################################################################
' # VERSION    : 1.0                                                           #
' # FILE       : ClearCachedProfile.vbs                                        #
' # CLASS      : Script                                                        #
' # LANGUAGE   : VB Script                                                     #
' # LOG FILE   : "%SystemRoot%\ClearCachedProfile.log"                         #
' ##############################################################################



On Error Resume Next



ClearNormalMonths = 12 ' #### CLEAR USER PROFILE CACHE AFTER * MONTHS
ClearMandatoryWeeks = 1 ' #### CLEAR MANDATORY USER PROFILE CACHE AFTER * WEEKS



Set objRegistry = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set wshShell = CreateObject("WScript.Shell")

LogFilePath = wshShell.ExpandEnvironmentStrings("%SystemRoot%") & "\ClearCachedProfile.log"
If objFSO.FileExists(LogFilePath) = True Then
Set f = objFSO.GetFile(LogFilePath)
If DateDiff("m",f.DateLastModified,Now()) > 1 Then objFSO.DeleteFile LogFilePath End If
End If
Set objFile = objFSO.OpenTextFile(LogFilePath, 8, True)


if objRegistry.EnumKey(&H80000002, "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList", valueNames1) = 0 then
	if isArray(valueNames1) then
		for i1 = 0 to UBound(valueNames1)
		LocalNTuser = ""
		LocalSID = valueNames1(i1)
		objRegistry.GetStringValue &H80000002, "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\" & LocalSID, "Guid", GuidValue
		objRegistry.GetStringValue &H80000002, "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\" & LocalSID, "ProfileImagePath", PathValue

		If InStr(LocalSID,"S-1-5-21-137065001-") > 0 Then

			Set objAccount = objWMIService.Get("Win32_SID.SID='" & Split(LocalSID,".",-1,1)(0) & "'")
				
			IsMandatory = ""
			If objFSO.FileExists(Trim(PathValue) & "\ntuser.man") = True Then
			LocalNTuser = Trim(PathValue) & "\ntuser.man"
			IsMandatory = "ON"
			End If
			If objFSO.FileExists(Trim(PathValue) & "\ntuser.dat") = True Then
			LocalNTuser = Trim(PathValue) & "\ntuser.dat"
			IsMandatory = "OFF"
			End If
				
			SpuriousProfile = "No"
			If objFSO.FolderExists(Trim(PathValue)) = False Then
			SpuriousProfile = "Yes"
			End If
				
			LastLogonW = 0
			LastLogonM = 0
			If IsMandatory <> "" Then
			Set f = objFSO.GetFile(LocalNTuser)
			LastLogonW = DateDiff("w",f.DateLastModified,Now())
			LastLogonM = DateDiff("m",f.DateLastModified,Now())
			Set f = Nothing
			End If
				
				
				
				
			ClearProfile = 0
			If IsMandatory = "ON" And LastLogonW > ClearMandatoryWeeks Then ClearProfile = 1 End If
			If IsMandatory = "OFF" And LastLogonM > ClearNormalMonths Then ClearProfile = 1 End If
			If SpuriousProfile = "Yes" Then ClearProfile = 1 End If
				
				

			Wscript.Echo
			Wscript.Echo "Path = " & Trim(PathValue)
			Wscript.Echo "SID = " & LocalSID
			Wscript.Echo "GUID = " & GuidValue
			Wscript.Echo "Mandatory = " & IsMandatory
			Wscript.Echo "LastLogon = " & LastLogonW & " Weeks - " & LastLogonM & " Months"
			Wscript.Echo "Spurious Profile = " & SpuriousProfile
			Wscript.Echo "IS DELETABLE = " & ClearProfile
				
			If ClearProfile = 1 Then
			objRegistry.DeleteKey &H80000002, "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\" & LocalSID & "\Preference"
			objRegistry.DeleteKey &H80000002, "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\" & LocalSID
			objRegistry.DeleteKey &H80000002, "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileGuid\" & GuidValue
			objRegistry.DeleteKey &H80000002, "SOFTWARE\Microsoft\Windows NT\CurrentVersion\PolicyGuid\" & GuidValue
			If objFSO.FolderExists(Trim(PathValue)) = True Then wshShell.run "ccp.bat """ & Trim(PathValue) & "\""",1,1 End If
			End If
				
				

			If ClearProfile = 1 Then
			objFile.WriteLine ""
			objFile.WriteLine ""
			objFile.WriteLine ""
			objFile.WriteLine Now()
			objFile.WriteLine ""
			objFile.WriteLine "Path = " & Trim(PathValue)
			objFile.WriteLine "SID = " & LocalSID
			objFile.WriteLine "GUID = " & GuidValue
			objFile.WriteLine "Mandatory = " & IsMandatory
			objFile.WriteLine "LastLogon = " & LastLogonW & " Weeks - " & LastLogonM & " Months"
			objFile.WriteLine "Spurious Profile = " & SpuriousProfile
			objFile.WriteLine ""
			objFile.WriteLine "=================================================="
			End If

		End If

		Set objAccount = Nothing
		next
	end if
end if

objFile.Close
Set objAccount = Nothing
Set objRegistry = Nothing
Set objWMIService = Nothing
Set objFSO = Nothing
Set wshShell = Nothing
Set objFile = Nothing
Set f = Nothing


'end script ClearCachedProfile